Adventuron - Cookbook

######################################
#  Adventuron                        #
######################################

start_at                 = lakeside

######################################
#  Booleans                          #
######################################

booleans {
   is_boat_fixed       : boolean "false" ;
   is_boat_at_lakeside : boolean "true" ;
}

######################################
#  Locations                         #
######################################

locations {
   lakeside     : location  "You are at the lakeside" ;
   inside_boat  : location  "You are a boat." ;
   island_beach : location  "You are at a beach on an island" ;
}

on_describe {

   : if (is_at "inside_boat") {
      : if (is_boat_fixed == false) {
         : print "There is a hole in the boat." ;
      }
   }
}

######################################
#  On Command                        #
######################################

on_command {

   : match "enter boat;climb boat"  {
      : if (is_at "lakeside" || is_at "island_beach") {
         : goto "inside_boat" ;
         : print "You climb inside the boat" ;
         : press_any_key ;
         : redescribe;

      }
   }

   : match "leave boat;exit _"  {
      : if (is_at "inside_boat") {
         : goto "old_boat" ;
         : print "You climb out of the boat" ;
         : press_any_key ;
         : redescribe;

      }

   }

   : match "repair hole;repair boat"  {
      : if (is_at "inside_boat" && is_boat_fixed == false) {
         : print "You repair the hole in the boat" ;
         : set_true "is_boat_fixed" ;
         : press_any_key ;
         : redescribe;
      }
   }

   : match "row boat"  {
      : if (is_at "inside_boat") {
         : if (is_boat_fixed) {
            : if (is_boat_at_lakeside) {
               : print "You row the boat to the island." ;
               : set_false "is_boat_at_lakeside" ;
               : create "old_boat" target = "island_beach" ;

            }
            : else {
               : print "You row the boat to the lakeside." ;
               : set_true "is_boat_at_lakeside" ;
               : create "old_boat" target = "lakeside" ;
            }
         }
         : else {
            : print "You can't row the boat with the hole in it." ;
         }
      }
   }
}

objects {
   old_boat : object "an old boat" at = "lakeside" ;
}

themes {
   my_theme : theme {
      lister_exits {
         is_list_enter                        = false
         is_list_exit                         = false
      }
   }
}

start_at = village

locations {
   village  : location "You are in a village." ;
}

objects {
   lamp : object "a lamp" at = "village" ;
}

on_command {
   : match "get lamp"  {
      : if (is_beside "lamp") {
         : get "lamp" quiet = "true" ;
         : if (is_carried "lamp") {
            : print "You pick up the dusty lamp" ;
            : press_any_key ;
            : redescribe;
         }
      }
   }
}

start_at = village

locations {
   village  : location "You are in a village." ;
}

objects {
   lamp : object "a lamp" at = "village" get_message = "You pick up the dusty lamp";
}

start_at = village

locations {
   village  : location "You are in the village" ;
   forest_1 : location "You are in a forest" ;
   forest_2 : location "You are in a spooky forest" ;
}
connections {
   from, direction, to = [
      village, east, forest_1,
      forest_1, east, forest_2,
   ]
}

barriers {
   block_forest_path : block {
      location               = forest_1
      block_when_not_carried = lamp
      message                = You need a light source to go into the dark forest.
   }
}
objects {
   lamp : object "a magical glowing lamp" at = "village" ;
}

themes {
   my_theme : theme {
      theme_settings {
         font = clairsys_10
      }
   }
}

start_at        = stream
redescribe = auto_beta
locations {
   stream   : location "You are by the side of a lovely stream.\nType <WEAR CLOAK<12>> to enable block, type <REMOVE CLOAK<12>> to disable block.";
   forest   : location "You are in a grand forest." ;
   old_hut  : location "You are in an old hut." ;
}
connections {
   from, direction, to = [
      stream, north, forest,
      forest, east, old_hut,
   ]
}
barriers {
   block_disorientate : block {
      block_when_worn = cloak
      message         = You are so confused, you can't seem to move anywhere.
   }
}
objects {
   cloak : object "the cloak of disorientation" wearable = "true" at = "inventory" ;
}

start_at = village

locations {
   village : location "You are in the village. Type TELEPORT to go to the location of the lamp." ;
   forest  : location "You are in a forest. Type TELEPORT to go to the location of the lamp." ;
}

connections {
   from, direction, to = [
      village, east, forest,
   ]
}

on_command {
   : match "teleport _"  {
      : print "You goto the location of the lamp" ;
      : goto "lamp" ;
      : press_any_key ;
      : redescribe;
   }
}

objects {
   lamp : object "a lamp" at = "forest" ;
}

start_at = village

locations {
   village  : location "You are in the village. Type SCORE to see your score." ;
}

integers {
   // Set the default score to zero here
   score : integer "0" ;
}

on_command {
   : match "score _"  {
      // Note that CONTROL + SPACE only works on blank lines in these blocks
      : print {(
         "Your score is " +
         score +
         "."
      )}
   }
}

start_at = village

strings {
   day_of_week : string "Wednesday" ;
}
locations {
   village  : location "You are in the village. It is {day_of_week}." ;
}
booleans {
   is_wednesday : boolean "false" ;
}

start_at = village

strings {
   wednesday : string "Wednesday" ;
   not_wednesday : string "Not Wednesday" ;
}
locations {
   village  : location "You are in the village. It is {is_wednesday ? wednesday : not_wednesday}.\nType LOOK to refresh the dynamic location description." ;
}
booleans {
   is_wednesday : boolean "false" ;
}
on_tick {
   : if (is_wednesday) {
      : set_false "is_wednesday" ;
   }
   : else {
      : set_true "is_wednesday" ;
   }
}

start_at = village

locations {
   village  : location "You are in the village. It is {is_wednesday ? `wednesday` : `not wednesday`}.\nType LOOK to refresh the dynamic location description." ;
}
booleans {
   is_wednesday : boolean "false" ;
}
on_tick {
   : if (is_wednesday) {
      : set_false "is_wednesday" ;
   }
   : else {
      : set_true "is_wednesday" ;
   }
}

start_at = village

locations {
   village  : location "You are in the village. {is_wednesday ? `It is wednesday.`}\nType LOOK to refresh the dynamic location description." ;
}
booleans {
   is_wednesday : boolean "true" ;
}
on_tick {
   : if (is_wednesday) {
      : set_false "is_wednesday" ;
   }
   : else {
      : set_true "is_wednesday" ;
   }
}

start_at = village

locations {
   village  : location "You are in the village. {is_wednesday ? `It is {is_wednesday ? `{wed}.`}.`}\nType LOOK to refresh the dynamic location description." ;
}


strings{
   wed : string "Wednesday";
}
booleans {
   is_wednesday : boolean "true" ;
}
on_tick {
   : if (is_wednesday) {
      : set_false "is_wednesday" ;
   }
   : else {
      : set_true "is_wednesday" ;
   }
}

start_at                 = my_location

locations {
   my_location : location "You are in a room. This is your {gane_count_nice} game." ;
}

integers {
   // The variable will survive a game restart (or game over)
   game_count : integer "0" scope="survivor";
}

on_startup {
   : increment "game_count" ;
}

strings {
   // NOTE : This syntax is due to change (slightly) in later revisions of Adventuron.
   gane_count_nice : dynamic_string {(
       game_count +
         (game_count % 10 == 1 ? "st" :
          game_count % 10 == 2 ? "nd" :
          game_count % 10 == 3 ? "rd" : "th")
   )}
}

game_information {
   game_name        = Survivor 1
   game_shortname   = S1
   written_by       = Adventuron Documentation
   year_of_original = 2020
   year_of_release  = 2020
   uuid             = GENERATE A UUID HERE BEFORE RUNNING THIS EXAMPLE - https://www.uuidgenerator.net/
   short_synopsis   = Solve the adventure
   game_version     = 1.0.0
}

start_at = my_location

locations {
   my_location : location "You are in a room." ;
}

integers {
   survivor : integer "100" scope="survivor";
}

on_describe {
   : print {("Survivor = " + survivor)}
}

on_command {

   : match "test _"  {
      : increment "survivor" ;
      : print {("Survivor = " + survivor)}
   }

}

game_information {
   game_name        = Survivor 2
   game_shortname   = S2
   written_by       = Adventuron Documentation
   year_of_original = 2020
   year_of_release  = 2020
   uuid             = GENERATE A UUID HERE BEFORE RUNNING THIS EXAMPLE - https://www.uuidgenerator.net/
   short_synopsis   = Solve the adventure
   game_version     = 1.0.0
}

start_at = village

locations {
   village  : location "You are in the village." ;
}

on_tick {
   : execute_one_at_random {
      : print "one" ;
      : print "two" ;
      : print "three" ;
      : print "four" ;
   }
}

start_at                 = my_location
locations {
   my_location : location "Hello {name}. You are in a room." ;
}
strings {
   name : string "";
}
on_startup {
   : ask_string
      question                  = "What is your name?"
      confirm_negative_question = "You entered your name as \"{name}\".\nWould you like to change the name?"
      var                       = "name"
   ;
}

start_at                 = my_location

locations {
   my_location : location "You are in a bright kitchen.\n{toast_thought}" ;
}

strings {
   // NOTE : This syntax is due to change (slightly) in later revisions of Adventuron.
   toast_thought : dynamic_string {(
      is_liking_toast ?
      "I can't stop thinking about delicious toast." :
      "I can't stop thinking about how disgusting toast is."

   )}
}

booleans {
   is_liking_toast : boolean "false" ;
}

on_startup {
   : ask_bool {
      question   = Do you like toast?
      yes_answer = Yes, I like toast very much
      no_answer  = No, toast is not something that appeals to me at all
      var        = is_liking_toast
   }
}

start_at      = treasure_room
treasure_room = treasure_room
locations {
   treasure_room : location "The treasure room";
   tomb          : location "A tomb" ;
}
connections {
   from, direction, to = [
      treasure_room, east, tomb,
   ]
}
objects {
   lamp : object "a lamp" at = "tomb" treasure = "true" ;
}

start_at      = treasure_room
treasure_room = treasure_room

locations {
   treasure_room : location "The treasure room";
   tomb          : location "A tomb" ;
   stream        : location "A stream" ;
}

connections {
   from, direction, to = [
      treasure_room, east, tomb,
      treasure_room, south, stream,
   ]
}

objects {
   lamp : object "<a lamp<14>>" at = "tomb"   treasure = "true" ;
   ring : object "<a ring<14>>" at = "stream" treasure = "true" ;
}

start_at = river

locations {
   river : location "You are in the river.\n" ;
}

on_tick {
   : if (is_just_entered () ) {
      : if (is_at "river") {
         : play_music sound="song_river";
      }
      : else {
         : stop_music;
      }
   }
}

assets {
   sounds {
      // NOTE :: Make sure that only reference content you are
      //         licensed to use.

      // ALSO :: You can use relative paths here, but you can only
      //         test in compiled versions of your code (not the
      //         web editor)
      song_river : sound_sample "https://somedomainid.com/sounds/river.mp3" ;
   }
}

start_at = village

locations {
   village  : location "You are in the village" ;
   forest_1 : location "You are in a forest" ;
   forest_2 : location "You are in a spooky forest" ;
}

// Zones are ways to define a group of locations. In this case
// we just choose the locations we will mark as dark.
zones {
   dark_zone : zone {
      locations = [ forest_1, forest_2 ]
   }
}
booleans {
   // A dynamic boolean is an expression that is
   // freshly calculated every time it is referred to

   // The part within the {( )} characters is just like
   // an expression you would find between the () of an :if
   // statement

   // NOTE : This syntax is due to change (slightly) in later revisions of Adventuron.
   is_dark : dynamic_boolean {(
      is_at "dark_zone" &&
      is_present "lamp" == false
   )}
}
game_settings {
   dark_expression = is_dark
}

connections {
   from, direction, to = [
      village, east, forest_1,
      forest_1, east, forest_2,
   ]
}
objects {
   lamp : object "a magical glowing lamp" at = "village" ;
}

// Setting the dark message is optional here
themes {
   my_theme : theme {
      system_messages {
         it_is_dark = Darkness surrounds you !
      }
   }
}

start_at                 = start_room

locations {
   start_room : location "You are in a lovely treasure room." {

      on_command {
         : match "test _"  {
            : print "Should be blocked in the dark!" ;
            : done ;
         }
      }

   }
}

objects {
   // The crown is in the same location as the player at the start, but GET is blocked
   // so cannot be taken even if the player knows it's there.
   crown : object "a gold crown" at = "start_room" ;

   // The lamp description is dynamic, based on the state of the lamp
   lamp  : object "a lamp{is_lamp_lit ? ` (lit)`}" at = "inventory" ;

}

booleans {

   is_lamp_lit : boolean "false" ;

   is_dark     : dynamic_boolean  {(
      is_at "start_room" && is_lamp_lit == false
   )}

   // Everything except [movement, quit, save, load,
   // inventory, turns, look] is banned in the dark.
   is_inaccessible_darkness_verb : dynamic_boolean {(
      (
         /* is movement command matches any system compass direction verb + all aliases */
         is_movement_command () ||
         verb_is "quit"         ||
         verb_is "save"         ||
         verb_is "load"         ||
         verb_is "inventory"    ||
         verb_is "turns"        ||
         verb_is "look"
      ) == false
   )}
}



on_pre_command {

   // This comes before the darkness action block
   // so we can perform this action in the dark.

   : match "light lamp"  {
      : if (is_carried "lamp" && is_lamp_lit == false) {
         : set_true "is_lamp_lit" ;
         : print "You light the lamp" ;
         : press_any_key ;
         : redescribe;
      }
   }

   // Blocks everything except movement, quit, save, load, inventory, turns, look
   : if (is_dark && is_inaccessible_darkness_verb) {
      : print "You fumble in the dark." ;
      : done ;
   }
}


game_settings {
   // Tells Adventuron when to override the location description with
   // the darkness message (in the theme system messages), plus will remove direction list
   // and object list from the location layout (when is_dark resolves to true)
   dark_expression = is_dark
}

themes {
   my_theme : theme {
      colors {
         // Set the darkness pen colour to dark blue.
         dark_pen = 9
      }
      system_messages {
         it_is_dark = Darkness surrounds you.
      }
   }
}

start_at = barn
template = talp

game_settings { dark_expression = "is_dark" }

booleans {
   is_dark : dynamic_boolean {( is_at "dark_zone" && is_carried "lamp" == false )}
}

strings {
   header_text : dynamic_string {( is_dark ? "IN THE DARK" :  h() )}
}

locations {
   barn  : location "You are in a barn."  header = "BARN" ;
   field : location "You are in a field." header = "FIELD" ;
}

connections {
   from, direction, to = [
      barn, east, field,
   ]
}

objects {
   lamp : object "a lamp" at = "barn" ;
}

zones {
   dark_zone : zone {
      locations  = [ field ]
   }
}

themes {
   my_theme : theme {
      status_bar {
         : dynamic_text "header_text" ;
         : fixed_text "MY GAME NAME HERE" ;
      }
      colors {
         status_bar_paper = 1
         status_bar_pen   = 14
      }
   }
}

start_at = lakeside

locations {
   lakeside       : location "You are by the side of a lake.";
   forest         : location "You are in a forest." ;
   treetop        : location "You are in a treetop." ;
}

connections {
   from, direction, to = [
      lakeside,       east,  forest,
      forest,         up,    treetop,
   ]
}

objects {
   lamp : object "a lamp" at = "forest"  ;
}

zones {
   forest_zone : zone { locations  = [ treetop, forest ] }
   treetop_zone : zone { locations  = [ treetop ] }
}

on_tick {

   : if ( is_at "forest_zone" ) {
      : append "The player is in the foresty zone. " ;
   }

   : if ( is_within { outer = "forest_zone" inner = "lamp" } ) {
      : append "The lamp is within the foresty zone. " ;
   }

   : if ( is_within {  outer = "treetop_zone" inner = "lamp" } ) {
      : append "The lamp is within the treetop zone. " ;
   }

}

start_at = lakeside

locations {
   lakeside       : location "You are by the side of a lake.";
   forest         : location "You are in a forest." ;
   treetop        : location "You are in a treetop." ;
}

zones {
   forest_zone  : zone { locations  = [ treetop, forest ] }
   treetop_zone : zone { locations  = [ treetop ] }
}

connections {
   from, direction, to = [
      lakeside,       east,  forest,
      forest,         up,    treetop,
   ]
}

objects {
   lamp : object "a lamp" at = "forest"  ;
}

booleans {
   is_player_in_forest_zone : dynamic_boolean {( is_at "forest_zone" )}
   is_lamp_in_forest_zone   : dynamic_boolean {( is_within { outer = "forest_zone"  inner = "lamp" } )}
   is_lamp_in_treetop_zone  : dynamic_boolean {( is_within { outer = "treetop_zone" inner = "lamp" } )}
}

on_tick {
   : if ( is_player_in_forest_zone ) { : append "The player is in the foresty zone. " ;   }
   : if ( is_lamp_in_forest_zone )   { : append "The lamp is within the foresty zone. " ; }
   : if ( is_lamp_in_treetop_zone )  { : append "The lamp is within the treetop zone. " ; }
}

graphics {
  // The png file will be read from the same path as the game html file
   blah : png "mypng.png";

  // This file should be referencable from anywhere (but only if playing
  // online).
  // Absolute paths can be convenient in development, but for packaging,
  // relative paths are better.

   blah2 : jpeg "https://somedomain.com/somepath/myjpeg.jpg";
}