Adventuron - Targetting 8-Bit Micros

// Good
: match "examine _" {

   : match "examine hat" {
      // Content
   }

   : match "examine lamp" {
      // Content
   }
}

// Bad
: match "examine _" {
   if (is_awake) {
       : match "examine hat" {
          // Content
       }

       : match "examine lamp" {
          // Content
       }
   }
}

start_at = hut
locations {
    hut : location "You are in a hut." {
       on_describe {
          : if (chance(50)) {
             : print "You feel a breeze.";
          }
       }
    }
}

: match "examine hat" {

    // Level 0

    : if (a) {
       // Level 1
       : if (b) {
          // Level 2
          : if (c) {
             // Level 3
             : if (d) {
                // Level 4
             }
             : else if (e) {
                // Level 4
             }
             : else if (f) {
                // Level 4
             }
             : else {
                // Level 4
             }
          }
          : else_if (g) {
             // Level 3
          }
          : else {
             // Level 3
          }
       }
       : else {
          // Level 2
       }
    }
    : else {
      // Level 1
    }

    // Level 0

    : if (h) {
       // Level 1
    }
    : else {
       // Level 1
    }

    // Level 0

    : if (i) {
       // Level 1
    }
    : else if (j) {
       // Level 1
    }
    : else {
       // Level 1
    }

    // Level 0

}

NOUN COLLISION DETECTED (CHOPPED TO 5 LETTERS): WATER

start_at = lake

locations {
   lake   : location "You are by a lake" ;
}

objects {
   water      : object "some water (in the beaker)" at = "lake" ;
   waterfall  : scenery "a waterfall" at = "lake";
}

vocabulary {
   # Creates a noun synonym for water and waterfall.
   : noun / aliases = [water, waterfall]
}

start_at = my_location
​
locations {
   my_location : location "You are in a room." ;
}

​integers {
​   // Only required if you are using store_random
   randomvar : integer ;
}

​on_tick {
   // GOTCHA NOTICE -- Chance is (currently) not working with its parameter in double quotes.
   //                  Use as listed here. This is on the bug list.
   : if (chance (50)) {
      // Will print hello 50 percent of the time
      : print "HELLO" ;
   }

   // Stores the random result in randomvar
   : store_random var = "randomvar" ;

   : if (randomvar < 33) {
      // Will print GOODBYE 33 percent of the time
      : print "GOODBYE" ;
   }
}

start_at = lakeside

locations {
   lakeside     "You are by the side of a <beautiful lake<13>>." ;
   forest       "You are on the <forest path<12>>.\nTall trees tower over you on both sides." ;
   outside_cave "You are standing outside the <cave of magic<11>>." ;
   inside_cave  "You are inside the <cave of magic<14>>." ;
}

connections {

   from, direction, to = [
      lakeside,     north,        forest,
      forest,       north,        outside_cave,
      outside_cave, north_oneway, inside_cave,
   ]
}

objects {
   troll          : scenery "<an enormous troll (guarding cave to north)<10>>" at = "outside_cave" ;
   sleeping_troll : scenery "an enormous troll (sleeping)" ;
   apple          : object  "<an apple<12>>" ;
   treasure       : object  "<a pile of treasure<14>>" at = "inside_cave" ;
}

barriers {
   block_cave : block {
      location               = inside_cave
      message                = THE TROLL IS GUARDING THE CAVE.
      block_when_exists      = troll
   }
}

on_startup {
   : print "You must find the treasure in the cave of magic.";
   : press_any_key ;
}

on_describe {

   : if (is_present "troll") {
      : print "The troll says, \"THE CAVE IS MINE, GO AWAY\"." ;
   }

   : if (is_at "inside_cave" ) {
      : print "CONGRATULATIONS !" ;
      : print "YOU WON THE GAME !" ;
      : print "YOUR RANKING IS : JUNIOR ADVENTURER !" ;
      : press_any_key ;
      : clear_screen;
      : win_game ;
   }
}

on_command {

   : match "examine trees"  {
      : if (is_at "forest") {
         : print "Apple trees." ;
      }
   }

   : match "pick apple;get apple"  {
      : if (is_at "forest" && has_not_created "apple") {
        : print "You take an <APPLE<12>> from one of the trees." ;
        : pocket "apple";
      }
   }

   : match "examine troll;talk troll"  {
      : if (is_present "troll") {
         : clear_screen;
         : print "\"I'M SO HUNGRY\", says the enormous TROLL in the deepest possible voice." ;
         : press_any_key ;
         : redescribe;
      }
   }

   : match "give apple"  {
      : if (is_present "troll" && is_carried "apple") {
         : print "The troll grabs the apple from you hungrily. Unfortunately (for the troll), the apple is an <ENCHANTED APPLE<12>>, and sends the troll directly to sleep." ;
         : destroy "apple" ;
         : swap o1 = "troll"  o2 = "sleeping_troll" ;
         : press_any_key ;
         : redescribe;
      }
   }

}

#########################################################
## Dog And Castle - By Chris Ainsley (CC0, Public Domain)
#########################################################

start_at   = forest
redescribe = auto_beta

locations {
   hut    : location "You are in the wizard's hut." ;
   forest : location "You are in the forest." ;
   castle : location "You are in the castle." ;
}

connections {
   from, direction, to = [
      hut,    west,  forest,
      forest, north, castle
   ]
}

objects {
   bone     : object  "a bone"         msg = "A fibula.";
   cupboard : scenery "a cupboard"     msg = "Empty."               at = "hut" ;
   dog      : scenery "a fierce doggy" msg = "A serious chihuahua." at = "forest" ;
}

on_startup {
   : print "Reach the castle!" ;
   : press_any_key ;
}

barriers {
   block_castle : block {
      location            = castle
      message             = The doggy will not allow it.
      block_when_exists   = dog
      show_blocked_exit   = true
   }
}

on_command {
   : match "open cupboard; examine cupboard"  {
      : if (is_beside "cupboard" && has_not_created "bone") {
         : print "You find something ..." ;
         : create "bone" ;
      }
   }
   : match "give bone; throw bone"  {
      : if (is_beside "dog" && is_carried "bone") {
         : print "The doggy approves of your offering and salutes you with a paw before fading into nothingness." ;
         : destroy "dog" ;
      }
   }
}

on_tick {
   : if (is_at "castle") {
      : print "You have reached the castle! Well done." ;
      : win_game ;
   }
}

game_settings {
   daad_exporter_tags = [
      "status_bar = 10",
      "extra_rows = 1"
   ]
}

start_at = hut

locations {
   hut : location "You are in a hut.";

   // The location is just for displaying choices.
   // As these are all dynamic, there is no location text.
   choice_dialog_1 : location "";
}

objects {
   // The breadcrumb is used as a marker for the location to return to (at the end of choices)
   breadcrumb : object "a breadcrumb" ;
   man        : scenery "a man" start_at = "hut" ;
}


integers {
   // Used to track how many choices are available.
   // Always add a failsafe choice to return to the breadcrumb
   num_choices_displayed : integer "0" ;
}

booleans {

   display_choice_rhino : boolean "true" ;
   display_choice_aardvark : boolean "true" ;
   display_choice_sorcerer : boolean "true" ;

}

on_describe {

   // To let the 'player' how to select choices.
   // You can trigger choices however you like in your
   // own game.

   : if (is_present "man") {
      : print "Type CHOICES says the man." ;
   }

   // If at the choice dummy location 'choice_dialog_1'
   // Then show the context of the question, and the choices
   // available.

   : if (is_at "choice_dialog_1") {
      : set_integer var = "num_choices_displayed" value = "0" ;

      : print "The man says ... make your choices ...";

      : if (display_choice_rhino) {
          : increment "num_choices_displayed";
          : print "Type 'rhino' to do something.";
      }
      : if (display_choice_aardvark) {
         : increment "num_choices_displayed";
         : print "Type 'aardvark' to do something.";
      }
      : if (display_choice_sorcerer) {
          : increment "num_choices_displayed";
          : print "Type 'sorcerer' to do something.";
      }

      // Always add a failsafe choice to return to the breadcrumb
      : if (num_choices_displayed == 0) {
         : print "No more choices remain. Type 'return' to leave the choice selection dialog.";
      }
   }
}

on_command {

   : match "choices _"  {
      // Creates the breadcrumb object in the current location.
      : create "breadcrumb" ;
      : goto "choice_dialog_1" ;
      : redescribe;

   }

   // NOTE: You can't put an 'if' directly underneath 'on_command'
   //       in 8-bit compatibility mode.

   // All choices need to be placed at top level of the on_command block
   // This isn't perfect, but it is all that is available for now.
   // I'll work on local on_command handlers at location level which should tidy this up a bit.

   : match "rhino _"  {
      // Always have to duplicate the logic
      // from the choice display section (on_describe)
      : if (is_at "choice_dialog_1" && display_choice_rhino) {
         : set_false "display_choice_rhino" ; // Removes the choice dynamically
         : print "You chose rhino (rhino will no longer be a choice)." ;
         : press_any_key ;
         : gosub "return_to_breadcrumb" ;
      }
   }

   : match "aardvark _"  {
      : if (is_at "choice_dialog_1" && display_choice_aardvark) {
         : set_false "display_choice_aardvark" ; // Removes the choice dynamically
         : print "You chose aardvark (aardvark will no longer be a choice).";
         : press_any_key ;
         : gosub "return_to_breadcrumb" ;

      }
   }
   : match "sorcerer _"  {
      : if (is_at "choice_dialog_1" && display_choice_sorcerer) {
         : set_false "display_choice_sorcerer" ; // Removes the choice dynamically
         : print "You chose sorcerer (sorcerer will no longer be a choice)." ;
         : press_any_key ;
         : gosub "return_to_breadcrumb" ;
      }
   }

   : match "return _"  {
      // Always add a failsafe choice to return to the breadcrumb
      : if (is_at "choice_dialog_1" && num_choices_displayed == 0) {
         : gosub "return_to_breadcrumb";
      }
   }

}

subroutines {
   return_to_breadcrumb : subroutine {
      : goto "breadcrumb" ;
      : destroy "breadcrumb" ;
      : redescribe;
   }
}